home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
NT Sources
/
Infomagic - NT Source Volume 1 (Disc 1 of 2).iso
/
network
/
pcdctrla.exe
/
PCDCTRL.EXE
/
STARTTSR.EN_
/
STARTTSR.EN
Wrap
Text File
|
1998-01-23
|
5KB
|
122 lines
REM Edit the above SET command if you wish to run the PC-Duo DOS Client from
REM a drive other than your current default, or if you want to load it from a
REM different subdirectory. E.g. SET PCDDIR=D:\TOOLS will load the DOS Client
REM from the D:\TOOLS area.
ECHO -------------------------------------------------------------------------------
ECHO * Starting the NetSupport PC-Duo DOS Client
ECHO * PC-Duo v3.72
ECHO * Copyright 1997 PCI, Vector Networks Limited
REM Last update : DB 23-Jan-98
REM Check for a setup batch file, and execute it first if we find it.
if not exist %PCDDIR%\STARTTS1.BAT goto TS1DONE
REM Assume that we are not expected to delete this file automatically
SET PCDTIDY=
CALL %PCDDIR%\STARTTS1
REM Now see if we are supposed to wipe that file, now that it's been executed
if not %PCDTIDY%. == . DEL %PCDDIR%\STARTTS1.BAT
:TS1DONE
REM Now prepare to load the DOS Client. If this is a standalone workstation
REM with no network connection, LOCALIPX and IP- or NBBRIDGE must be loaded
REM already.
REM Make sure we have got the correct the DOS Client program (IPX or NetBIOS).
REM This is determined by environment variable PCDNW, which is prepended to
REM "CLIENT.EXE". If PCDNW is undefined or empty, we load the NetBIOS Client
REM NBCLIENT.EXE. If it is "IP", then we load the IPX Client IPCLIENT.EXE.
if "%PCDNW%" == "" SET PCDNW=NB
if exist %PCDDIR%\%PCDNW%CLIENT.EXE goto IMAGEOK
ECHO *
ECHO * ERROR : Unable to find the PC-Duo Client program %PCDDIR%\%PCDNW%CLIENT.EXE.
ECHO *
goto BADTSR
:IMAGEOK
REM We default to using the auto-name option which derives the Client's name
REM from the DOS Machine Name. This is normally appropriate for NetBIOS-based
REM networks, such as PATHWORKS and LAN Manager. If you are using PC-Duo on
REM a NetWare network, the DOS Machine Name is often not set, so you will
REM have to specify a name explicitly to allow the Client to load. If this was
REM done when the Client was installed, the appropriate command will have been
REM added to the setup batch file STARTTS1.BAT. You can change the value by
REM changing the PCDCMD 'environment variable' definition in STARTTS1.BAT.
REM
REM If you set the PCDCMD environment variable before calling this batch file,
REM it will be inserted at the front of the Client command, in place of the
REM "*" for the automatic name determination. This allows you to have a wide
REM range of PCs all using the same STARTTSR (either physically the same, by
REM loading it from a server), but with local configuration changes
REM established where necessary. Editing this file allows you to change the
REM options that are applied to _all_ PCs. Setting PCDCMD allows you to define
REM extras for individual PCs, as required.
REM
REM For instance, setting PCDCMD to "fred /k" before CALLing this batch file
REM will cause the Client to be started with a Client name of "FRED", and will
REM require the user on this PC to acknowledge any Control connect attempts.
REM This can be used to set individual passwords, or any other options.
REM
REM For example, include the following command in STARTTS1.BAT:-
REM
REM SET PCDCMD=* 1234567
REM
REM This will make the Client use the auto-name mechanism, while requiring a
REM Control user to enter the matching (un-encrypted) password before the
REM connection is allowed.
REM
REM The default Client options can be changed by adding another line to
REM STARTTS1.BAT to define a value for environment variable PCDOPTS.
REM For instance, if you want to make this Client run with File Transfer and
REM Broadcast Message Receipt disabled, you could use the following:-
REM
REM SET PCDOPTS=/f /i
if "%PCDCMD%" == "" SET PCDCMD=*
REM Now, load the DOS Client.
%PCDDIR%\%PCDNW%CLIENT %PCDCMD% %PCDOPTS%
if not errorlevel 1 goto STARTOK
:BADTSR
ECHO * An error occurred starting the PC-Duo Client.
ECHO -------------------------------------------------------------------------------
pause
goto END
:STARTOK
REM Now we check for any other procedure to be executed now that we've got the
REM Client loaded happily. See the comments for STARTTS1 for more explanation.
if not exist %PCDDIR%\STARTTS2.BAT goto TS2DONE
SET PCDTIDY=
CALL %PCDDIR%\STARTTS2
if not %PCDTIDY%. == . DEL %PCDDIR%\STARTTS2.BAT
:TS2DONE
ECHO * PC-Duo Client loaded successfully.
ECHO -------------------------------------------------------------------------------
REM Delete environment variables before exiting.
:END
SET PCDDIR=
SET PCDCMD=
SET PCDNW=
SET PCDOPTS=
SET PCDTIDY=