home *** CD-ROM | disk | FTP | other *** search
/ NT Sources / Infomagic - NT Source Volume 1 (Disc 1 of 2).iso / network / pcdctrla.exe / PCDCTRL.EXE / STARTTSR.EN_ / STARTTSR.EN
Text File  |  1998-01-23  |  5KB  |  122 lines
  1.  
  2. REM Edit the above SET command if you wish to run the PC-Duo DOS Client from
  3. REM a drive other than your current default, or if you want to load it from a
  4. REM different subdirectory. E.g. SET PCDDIR=D:\TOOLS will load the DOS Client
  5. REM from the D:\TOOLS area.
  6.  
  7. ECHO -------------------------------------------------------------------------------
  8. ECHO *                  Starting the NetSupport PC-Duo DOS Client
  9. ECHO *                                 PC-Duo v3.72
  10. ECHO *                 Copyright 1997 PCI, Vector Networks Limited
  11.  
  12. REM Last update : DB 23-Jan-98
  13.  
  14. REM Check for a setup batch file, and execute it first if we find it.
  15.  
  16. if not exist %PCDDIR%\STARTTS1.BAT goto TS1DONE
  17.  
  18. REM Assume that we are not expected to delete this file automatically
  19. SET PCDTIDY=
  20.  
  21. CALL %PCDDIR%\STARTTS1
  22.  
  23. REM Now see if we are supposed to wipe that file, now that it's been executed
  24.  
  25. if not %PCDTIDY%. == . DEL %PCDDIR%\STARTTS1.BAT
  26.  
  27. :TS1DONE
  28.  
  29. REM Now prepare to load the DOS Client. If this is a standalone workstation
  30. REM with no network connection, LOCALIPX and IP- or NBBRIDGE must be loaded
  31. REM already.
  32.  
  33. REM Make sure we have got the correct the DOS Client program (IPX or NetBIOS).
  34. REM This is determined by environment variable PCDNW, which is prepended to
  35. REM "CLIENT.EXE". If PCDNW is undefined or empty, we load the NetBIOS Client
  36. REM NBCLIENT.EXE. If it is "IP", then we load the IPX Client IPCLIENT.EXE.
  37.  
  38. if "%PCDNW%" == "" SET PCDNW=NB
  39.  
  40. if exist %PCDDIR%\%PCDNW%CLIENT.EXE goto IMAGEOK
  41.  
  42. ECHO *
  43. ECHO * ERROR : Unable to find the PC-Duo Client program %PCDDIR%\%PCDNW%CLIENT.EXE.
  44. ECHO *
  45. goto BADTSR
  46.  
  47. :IMAGEOK
  48.  
  49. REM We default to using the auto-name option which derives the Client's name
  50. REM from the DOS Machine Name. This is normally appropriate for NetBIOS-based
  51. REM networks, such as PATHWORKS and LAN Manager. If you are using PC-Duo on
  52. REM a NetWare network, the DOS Machine Name is often not set, so you will
  53. REM have to specify a name explicitly to allow the Client to load. If this was
  54. REM done when the Client was installed, the appropriate command will have been
  55. REM added to the setup batch file STARTTS1.BAT. You can change the value by
  56. REM changing the PCDCMD 'environment variable' definition in STARTTS1.BAT.
  57. REM
  58. REM If you set the PCDCMD environment variable before calling this batch file,
  59. REM it will be inserted at the front of the Client command, in place of the
  60. REM "*" for the automatic name determination. This allows you to have a wide
  61. REM range of PCs all using the same STARTTSR (either physically the same, by
  62. REM loading it from a server), but with local configuration changes
  63. REM established where necessary. Editing this file allows you to change the
  64. REM options that are applied to _all_ PCs. Setting PCDCMD allows you to define
  65. REM extras for individual PCs, as required.
  66. REM
  67. REM For instance, setting PCDCMD to "fred /k" before CALLing this batch file
  68. REM will cause the Client to be started with a Client name of "FRED", and will
  69. REM require the user on this PC to acknowledge any Control connect attempts.
  70. REM This can be used to set individual passwords, or any other options.
  71. REM
  72. REM For example, include the following command in STARTTS1.BAT:-
  73. REM
  74. REM SET PCDCMD=* 1234567
  75. REM
  76. REM This will make the Client use the auto-name mechanism, while requiring a
  77. REM Control user to enter the matching (un-encrypted) password before the
  78. REM connection is allowed.
  79. REM
  80. REM The default Client options can be changed by adding another line to
  81. REM STARTTS1.BAT to define a value for environment variable PCDOPTS.
  82. REM For instance, if you want to make this Client run with File Transfer and
  83. REM Broadcast Message Receipt disabled, you could use the following:-
  84. REM
  85. REM SET PCDOPTS=/f /i
  86.  
  87. if "%PCDCMD%" == "" SET PCDCMD=*
  88.  
  89. REM Now, load the DOS Client.
  90.  
  91. %PCDDIR%\%PCDNW%CLIENT %PCDCMD% %PCDOPTS%
  92. if not errorlevel 1 goto STARTOK
  93.  
  94. :BADTSR
  95. ECHO *                 An error occurred starting the PC-Duo Client.
  96. ECHO -------------------------------------------------------------------------------
  97. pause
  98. goto END
  99.  
  100. :STARTOK
  101. REM Now we check for any other procedure to be executed now that we've got the
  102. REM Client loaded happily. See the comments for STARTTS1 for more explanation.
  103.  
  104. if not exist %PCDDIR%\STARTTS2.BAT goto TS2DONE
  105. SET PCDTIDY=
  106. CALL %PCDDIR%\STARTTS2
  107. if not %PCDTIDY%. == . DEL %PCDDIR%\STARTTS2.BAT
  108.  
  109. :TS2DONE
  110.  
  111. ECHO *                      PC-Duo Client loaded successfully.
  112. ECHO -------------------------------------------------------------------------------
  113.  
  114. REM Delete environment variables before exiting.
  115.  
  116. :END
  117. SET PCDDIR=
  118. SET PCDCMD=
  119. SET PCDNW=
  120. SET PCDOPTS=
  121. SET PCDTIDY=
  122.